Analysis Details

Beware the performance of String concatenation

es.uniovi.reflection.analyses.bloch.8.51

This rule detects when the operators + or += are used to concatenate any String inside a loop. This is risky since this operation already takes quadratic time and StringBuilder class must be used instead.

Computational Reflection Research Group

01-05-2026 13:28

Runtime Performance

Expression

MATCH ()<-[:COMPOUND_ASSIGNMENT_LHS| BINARY_OP_LHS]-(expression{actualType:"java.lang.String"})-[:COMPOUND_ASSIGNMENT_RHS| BINARY_OP_RHS]->()
WHERE expression.operator IN ['PLUS', 'PLUS_ASSIGNMENT']
WITH DISTINCT es.uniovi.reflection.codeanalysis.functions.getEnclStmt(expression) as concatStmt
CALL apoc.path.subgraphNodes(concatStmt, {
  relationshipFilter: "<BLOCK_ENCLOSES|<CASE_STATEMENT|<CASE_BODY|<CATCH_BLOCK|<DO_WHILE_STATEMENT|<FOREACH_STATEMENT|<FOR_LOOP_STATEMENT|<FOR_LOOP_UPDATE|<IF_THEN|<IF_ELSE|<LABELED_STATEMENT_ENCLOSES|<SWITCH_CASE|<SYNCHRONIZED_BLOCK|<TRY_BLOCK|<TRY_CATCH|<TRY_FINALLY|<VAR_DEC_INIT|<WHILE_STATEMENT",
  labelFilter: '/LOOP',
  minLevel: 0,
  uniqueness: 'NODE_GLOBAL',
  limit: 1
}) YIELD node as loop
WITH concatStmt, loop, es.uniovi.reflection.codeanalysis.functions.getEnclosingType(loop) as enclType
MATCH (enclosingCU:COMPILATION_UNIT)-[:DECLARES_TYPE | HAS_NESTED_TYPE]->(enclType)
RETURN '{"node":"+/+= STRING EXPRESSION","line":"'+concatStmt.lineNumber+'","column":"'+concatStmt.column+'","rule":"BLOCH-8.51","location":"'+enclosingCU.fileName+'","message":"You must not use the operator +/+= in line ' + concatStmt.lineNumber + ' of type ' + enclType.simpleName + ', since it performs in quadratic time, and is already inside a loop (line ' + loop.lineNumber + ')."}'